[SCRIPT] Script help needed

[Your Computer]

You're still working on this? Here's my working version of it. All four sticky areas have the same detach and attach functions. The local map variable names have the names of the sticky areas. Study, modify, etc...

PHP Code: (Select All)

const string[] oven_sticky_areas = {"OvenArea_1", "OvenArea_2", "OvenArea_3", "OvenArea_4"};
const string oven_object_name = "oven_object";
const string oven_door_name = "mansion_1";
const string oven_lever_name = "lever_simple01_22";

void OnStart()
    {
        SetEntityConnectionStateChangeCallback(oven_lever_name, "CheckIngredients");
    }

////////////LEVER CHECK/////////////////
void CheckIngredients(string &in asEntity, int alState)
    {
        if(alState == 1)
        {
            if (GetLocalVarInt(oven_sticky_areas[0]) == 1
             && GetLocalVarInt(oven_sticky_areas[1]) == 1
             && GetLocalVarInt(oven_sticky_areas[2]) == 1
             && GetLocalVarInt(oven_sticky_areas[3]) == 1)
            {
                AddDebugMessage("OvenPuzzle: Correct!", false);
                AddTimer("CompleteOvenPuzzle", 1, "CompleteOvenPuzzle");
            }

            else
            {
                AddDebugMessage("OvenPuzzle: Wrong!", false);
                SetMessage("Messages", "IncorrectCombination", 0);
            }
        }
    }

void AttachObjectOven(string &in asStickyArea, string &in asBodyName)
    {
        if (StringContains(asBodyName, oven_object_name))
            SetAllowStickyAreaAttachment(true);
        else
        {
            SetAllowStickyAreaAttachment(false);
            return;
        }

        AddDebugMessage(asStickyArea + " " + asBodyName, true);

        asBodyName = StringSub(asBodyName, 0, oven_object_name.length() + 2);
        AddDebugMessage(asBodyName, false);

        if (StringContains(asStickyArea, "1") && StringContains(asBodyName, "1"))
            SetLocalVarInt(asStickyArea, 1);

        else if (StringContains(asStickyArea, "2") && StringContains(asBodyName, "2"))
            SetLocalVarInt(asStickyArea, 1);

        else if (StringContains(asStickyArea, "3") && StringContains(asBodyName, "3"))
            SetLocalVarInt(asStickyArea, 1);

        else if (StringContains(asStickyArea, "4") && StringContains(asBodyName, "4"))
            SetLocalVarInt(asStickyArea, 1);
    }

void DetachObjectOven(string &in asStickyArea, string &in asBodyName)
    {
        SetLocalVarInt(asStickyArea, 0);
    }

void CompleteOvenPuzzle(string &in asTimer)
    {
        SetSwingDoorLocked(oven_door_name, false, true);
        SetMessage("Messages", "correctcombinationchemicals", 0);
    }