Scripting, need urgent help!

[Apjjm]

Anyway to delay the sounds just a tad so they dont sound so immediate, and the character doesnt have a 100% on time reaction?

Delaying sounds? Try this

Code: (Select All)

int getDigit(uint8 digit) {
    int d = digit-48; //48 is ASCII code for 0
    return ((d >= 0)&&(d<=9)) ? d : -1;
}
int parseStringINT(string str) {
    int output = 0;
    for(int i=0; i<str.length(); i++)
     {
      int digit = getDigit(str[i]);
      if(digit > -1) output = 10*output+digit;
     }
    return output;
}
void _delaysndPlay(string &in sndtmr)
{
  int i = parseStringINT(sndtmr);
  string name = GetLocalVarString("_delaysnd_Name_"+i);
  string file = GetLocalVarString("_delaysnd_File_"+i);
  string ent = GetLocalVarString("_delaysnd_Ent_"+i);
  float fade = GetLocalVarFloat("_delaysnd_Fade_"+i);
  bool save = (GetLocalVarInt("_delaysnd_Sv_"+i)==1);
  PlaySoundAtEntity(name,file,ent,fade,save);
}

//This is the function you want to call!
void delayPlaySoundAtEntity(float afDelay, string asSoundName, string asSoundFile, string asEntity, float afFadeTime, bool abSaveSound)
{
   int i = GetLocalVarInt("_delaysnd_Count");
   AddLocalVarInt("_delaysnd_Count",1);
   SetLocalVarString("_delaysnd_Name_"+i,asSoundName);
   SetLocalVarString("_delaysnd_File_"+i,asSoundFile);
   SetLocalVarString("_delaysnd_Ent_"+i,asSoundName);
   SetLocalVarFloat("_delaysnd_Fade_"+i,afFadeTime);
   SetLocalVarInt("_delaysnd_Sv_"+i,abSaveSound?1:0);
   AddTimer("_delaysnd_timer"+i,afDelay,"_delaysndPlay");
}

That above is a general purpose delay sound play function, you can mod the parameters to suit any functions actually. This was written out in the reply window, so might have a syntax error in it, but aside from that it will work.

It works by creating an integer var, which is an "index". Then when the function is called the index value is incremented and remembered. We then append the index number onto the end of each variable's name so it has a unique name. This index "key" is then put in the timers name too! When the timer expires, the callback function is called, and the index is parsed out of the timer's name. This is then used to access all the variables we just stored, and pass them into the function.